BukkitTelnet/build.gradle

plugins {
    id "java"
    id "maven-publish"
    id "de.eldoria.plugin-yml.bukkit" version "0.8.0"
    id "com.gradleup.shadow" version "9.2.2"
}

group = "me.totalfreedom"
version = "4.10"
description = "BukkitTelnet"

repositories {
    mavenCentral()
    maven {
        url = uri("https://jitpack.io")
        content {
            includeGroup("com.github.MilkBowl")
        }
    }
    maven {
        url = uri("https://repo.papermc.io/repository/maven-public/")
    }
}

dependencies {
    compileOnly "io.papermc.paper:paper-api:1.21.10-R0.1-SNAPSHOT"
    annotationProcessor "org.projectlombok:lombok:1.18.42"
    library "org.projectlombok:lombok:1.18.42"
    library "org.json:json:20250517"
    compileOnly("com.github.MilkBowl:VaultAPI:1.7.1") {
        exclude group: "org.bukkit", module: "bukkit"
    }
    implementation "org.apache.commons:commons-lang3:3.18.0"
    library "org.apache.logging.log4j:log4j-api:2.25.2"
    library "org.apache.logging.log4j:log4j-core:2.25.2"
}
tasks {
    jar {
        dependsOn(shadowJar)
    }
}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(21))
}

tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

bukkit {
    name = "BukkitTelnet"
    main = "me.totalfreedom.bukkittelnet.BukkitTelnet"
    apiVersion = "1.20"
    version = project.version
    description = "Telnet console access plugin."
    authors = ["bekvon", "Madgeek1450", "Prozza", "Taahh", "Telesphoreo"]
    softDepend = ["Vault"]
}

shadowJar {
    archiveBaseName.set("BukkitTelnet")
    archiveVersion.set("")
    archiveClassifier.set("")
}