plugins {
    id 'java'
    id 'net.minecrell.plugin-yml.paper' version '0.6.0'
}

group = 'dev.taah'
version = '0.0.1'

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }
}

dependencies {
    compileOnly "io.papermc.paper:paper-api:1.20.4-R0.1-SNAPSHOT"
    paperLibrary("net.dv8tion:JDA:5.0.0-beta.20") {
        exclude module: "opus-java"
    }
}

def targetJavaVersion = 17
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

paper {
    name = "Futura"
    version = project.version
    main = "dev.plex.futura.Futura"
    apiVersion = "1.20"
    authors = List.of("Taah")
    description = "Discord plugin bridge for Minecraft"
    website = "https://plex.us.org"
    loader = "dev.plex.futura.util.FuturaLibraryManager"
    generateLibrariesJson = true
}