From 55100761a33c5c0086e06078ed641ed86bf56a78 Mon Sep 17 00:00:00 2001
From: Kenzie Togami <ket1999@gmail.com>
Date: Wed, 10 Jul 2019 17:07:37 -0700
Subject: [PATCH] Migrate Core to Kotlin DSL

---
 buildSrc/src/main/kotlin/Versions.kt     |  1 +
 worldedit-core/build.gradle              | 53 ------------------------
 worldedit-core/build.gradle.kts          | 50 ++++++++++++++++++++++
 worldedit-core/doctools/build.gradle.kts |  6 +--
 4 files changed, 53 insertions(+), 57 deletions(-)
 delete mode 100644 worldedit-core/build.gradle
 create mode 100644 worldedit-core/build.gradle.kts

diff --git a/buildSrc/src/main/kotlin/Versions.kt b/buildSrc/src/main/kotlin/Versions.kt
index fd61ee13b..0f79cbfd1 100644
--- a/buildSrc/src/main/kotlin/Versions.kt
+++ b/buildSrc/src/main/kotlin/Versions.kt
@@ -2,4 +2,5 @@ object Versions {
     const val TEXT = "3.0.1"
     const val TEXT_EXTRAS = "3.0.2"
     const val PISTON = "0.4.2"
+    const val AUTO_VALUE = "1.6.5"
 }
diff --git a/worldedit-core/build.gradle b/worldedit-core/build.gradle
deleted file mode 100644
index a5b3bba63..000000000
--- a/worldedit-core/build.gradle
+++ /dev/null
@@ -1,53 +0,0 @@
-plugins {
-    id("java-library")
-    id("eclipse")
-    id("idea")
-    id("net.ltgt.apt-eclipse")
-    id("net.ltgt.apt-idea")
-}
-
-PlatformConfigKt.applyPlatformAndCoreConfiguration(project)
-
-configurations.all { Configuration it ->
-    it.resolutionStrategy { ResolutionStrategy rs ->
-        rs.force("com.google.guava:guava:21.0")
-    }
-}
-
-dependencies {
-    compile project(':worldedit-libs:core')
-    compile 'de.schlichtherle:truezip:6.8.3'
-    compile 'org.mozilla:rhino:1.7R5'
-    compile 'org.yaml:snakeyaml:1.9'
-    compile 'com.google.guava:guava:21.0'
-    compile 'com.google.code.findbugs:jsr305:1.3.9'
-    compile 'com.google.code.gson:gson:2.8.0'
-    compile 'com.googlecode.json-simple:json-simple:1.1.1'
-    compile 'org.slf4j:slf4j-api:1.7.26'
-
-    compileOnly project(':worldedit-libs:core:ap')
-    annotationProcessor project(':worldedit-libs:core:ap')
-    annotationProcessor "com.google.guava:guava:21.0"
-    def avVersion = "1.6.5"
-    compileOnly "com.google.auto.value:auto-value-annotations:$avVersion"
-    annotationProcessor "com.google.auto.value:auto-value:$avVersion"
-    //compile 'net.sf.trove4j:trove4j:3.0.3'
-    testCompile 'org.mockito:mockito-core:1.9.0-rc1'
-}
-
-tasks.withType(JavaCompile).configureEach {
-    dependsOn(":worldedit-libs:build")
-    it.options.compilerArgs.add("-Aarg.name.key.prefix=")
-}
-
-sourceSets {
-    main {
-        java {
-            srcDir 'src/main/java'
-            srcDir 'src/legacy/java'
-        }
-        resources {
-            srcDir 'src/main/resources'
-        }
-    }
-}
diff --git a/worldedit-core/build.gradle.kts b/worldedit-core/build.gradle.kts
new file mode 100644
index 000000000..6d268e843
--- /dev/null
+++ b/worldedit-core/build.gradle.kts
@@ -0,0 +1,50 @@
+plugins {
+    id("java-library")
+    id("net.ltgt.apt-eclipse")
+    id("net.ltgt.apt-idea")
+}
+
+applyPlatformAndCoreConfiguration()
+
+configurations.all {
+    resolutionStrategy {
+        force("com.google.guava:guava:21.0")
+    }
+}
+
+dependencies {
+    "compile"(project(":worldedit-libs:core"))
+    "compile"("de.schlichtherle:truezip:6.8.3")
+    "compile"("rhino:js:1.7R2")
+    "compile"("org.yaml:snakeyaml:1.9")
+    "compile"("com.google.guava:guava:21.0")
+    "compile"("com.google.code.findbugs:jsr305:1.3.9")
+    "compile"("com.google.code.gson:gson:2.8.0")
+    "compile"("com.googlecode.json-simple:json-simple:1.1.1")
+    "compile"("org.slf4j:slf4j-api:1.7.26")
+
+    "compileOnly"(project(":worldedit-libs:core:ap"))
+    "annotationProcessor"(project(":worldedit-libs:core:ap"))
+    // ensure this is on the classpath for the AP
+    "annotationProcessor"("com.google.guava:guava:21.0")
+    "compileOnly"("com.google.auto.value:auto-value-annotations:${Versions.AUTO_VALUE}")
+    "annotationProcessor"("com.google.auto.value:auto-value:${Versions.AUTO_VALUE}")
+    "testCompile"("org.mockito:mockito-core:1.9.0-rc1")
+}
+
+tasks.withType<JavaCompile>().configureEach {
+    dependsOn(":worldedit-libs:build")
+    options.compilerArgs.add("-Aarg.name.key.prefix=")
+}
+
+sourceSets {
+    main {
+        java {
+            srcDir("src/main/java")
+            srcDir("src/legacy/java")
+        }
+        resources {
+            srcDir("src/main/resources")
+        }
+    }
+}
diff --git a/worldedit-core/doctools/build.gradle.kts b/worldedit-core/doctools/build.gradle.kts
index 75a347ece..803e1078e 100644
--- a/worldedit-core/doctools/build.gradle.kts
+++ b/worldedit-core/doctools/build.gradle.kts
@@ -4,14 +4,12 @@ plugins {
     kotlin("jvm") version "1.3.41"
 }
 
+applyCommonConfiguration()
+
 tasks.withType<KotlinCompile> {
     kotlinOptions.jvmTarget = "1.8"
 }
 
-repositories {
-    jcenter()
-}
-
 dependencies {
     "implementation"(project(":worldedit-libs:core:ap"))
     "implementation"(project(":worldedit-core"))