102 lines
3.1 KiB
Kotlin
102 lines
3.1 KiB
Kotlin
import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
|
|
import net.minecrell.gradle.licenser.LicenseExtension
|
|
import org.gradle.api.JavaVersion
|
|
import org.gradle.api.Project
|
|
import org.gradle.api.plugins.JavaPluginConvention
|
|
import org.gradle.api.plugins.quality.CheckstyleExtension
|
|
import org.gradle.api.tasks.bundling.Jar
|
|
import org.gradle.api.tasks.javadoc.Javadoc
|
|
import org.gradle.external.javadoc.CoreJavadocOptions
|
|
import org.gradle.kotlin.dsl.apply
|
|
import org.gradle.kotlin.dsl.configure
|
|
import org.gradle.kotlin.dsl.get
|
|
import org.gradle.kotlin.dsl.getByName
|
|
import org.gradle.kotlin.dsl.getPlugin
|
|
import org.gradle.kotlin.dsl.register
|
|
import org.gradle.kotlin.dsl.the
|
|
import org.gradle.kotlin.dsl.withType
|
|
import org.gradle.kotlin.dsl.named
|
|
|
|
fun Project.applyPlatformAndCoreConfiguration() {
|
|
applyCommonConfiguration()
|
|
apply(plugin = "java")
|
|
apply(plugin = "maven")
|
|
apply(plugin = "checkstyle")
|
|
apply(plugin = "com.github.johnrengelman.shadow")
|
|
apply(plugin = "com.jfrog.artifactory")
|
|
apply(plugin = "net.minecrell.licenser")
|
|
|
|
ext["internalVersion"] = "$version;${rootProject.ext["gitCommitHash"]}"
|
|
|
|
configure<JavaPluginConvention> {
|
|
sourceCompatibility = JavaVersion.VERSION_1_8
|
|
targetCompatibility = JavaVersion.VERSION_1_8
|
|
}
|
|
|
|
configure<CheckstyleExtension> {
|
|
configFile = rootProject.file("config/checkstyle/checkstyle.xml")
|
|
toolVersion = "7.6.1"
|
|
}
|
|
|
|
// Java 8 turns on doclint which we fail
|
|
tasks.withType<Javadoc>().configureEach {
|
|
(options as CoreJavadocOptions).addStringOption("Xdoclint:none", "-quiet")
|
|
}
|
|
|
|
tasks.register<Jar>("javadocJar") {
|
|
dependsOn("javadoc")
|
|
archiveClassifier.set("javadoc")
|
|
from(tasks.getByName<Javadoc>("javadoc").destinationDir)
|
|
}
|
|
|
|
tasks.named("assemble").configure {
|
|
dependsOn("javadocJar")
|
|
}
|
|
|
|
artifacts {
|
|
add("archives", tasks.named("jar"))
|
|
add("archives", tasks.named("javadocJar"))
|
|
}
|
|
|
|
if (name == "worldedit-core" || name == "worldedit-bukkit") {
|
|
tasks.register<Jar>("sourcesJar") {
|
|
dependsOn("classes")
|
|
archiveClassifier.set("sources")
|
|
from(project.the<JavaPluginConvention>().sourceSets["main"].allSource)
|
|
}
|
|
|
|
artifacts {
|
|
add("archives", tasks.named("sourcesJar"))
|
|
}
|
|
tasks.named("assemble").configure {
|
|
dependsOn("sourcesJar")
|
|
}
|
|
}
|
|
|
|
tasks.named("check").configure {
|
|
dependsOn("checkstyleMain", "checkstyleTest")
|
|
}
|
|
|
|
applyCommonArtifactoryConfig()
|
|
|
|
configure<LicenseExtension> {
|
|
header = rootProject.file("HEADER.txt")
|
|
include("**/*.java")
|
|
}
|
|
}
|
|
|
|
fun Project.applyShadowConfiguration() {
|
|
tasks.named<ShadowJar>("shadowJar") {
|
|
archiveClassifier.set("dist")
|
|
dependencies {
|
|
include(project(":worldedit-libs:core"))
|
|
include(project(":worldedit-libs:${project.name.replace("worldedit-", "")}"))
|
|
include(project(":worldedit-core"))
|
|
}
|
|
exclude("GradleStart**")
|
|
exclude(".cache")
|
|
exclude("LICENSE*")
|
|
minimize()
|
|
}
|
|
}
|